if ($?tcsh) then
	set modules_shell="tcsh"
else
	set modules_shell="csh"
endif
#if ( $?MODULE_VERSION ) then
# 	setenv MODULE_VERSION_STACK 	"$MODULE_VERSION"
#else
# 	setenv MODULE_VERSION		"3.2.3"
# 	setenv MODULE_VERSION_STACK	"3.2.3"
#endif
#set exec_prefix='/usr/share/Modules/$MODULE_VERSION'
set exec_prefix='/usr/bin'

set prefix=""
set postfix=""

if ( $?histchars ) then
  set histchar = `echo $histchars | cut -c1`
  set _histchars = $histchars

  set prefix  = 'unset histchars;'
  set postfix = 'set histchars = $_histchars;'
else
  set histchar = \!
endif

if ($?prompt) then
  set prefix  = "$prefix"'set _prompt="$prompt";set prompt="";'
  set postfix = "$postfix"'set prompt="$_prompt";unset _prompt;'
endif

if ($?noglob) then
  set prefix  = "$prefix""set noglob;"
  set postfix = "$postfix""unset noglob;"
endif
set postfix = "set _exit="'$status'"; $postfix; test 0 = "'$_exit;'

#alias module $prefix'eval `'$exec_prefix'/bin/modulecmd '$modules_shell' '$histchar'*`; '$postfix
alias module $prefix'eval `'$exec_prefix'/modulecmd '$modules_shell' '$histchar'*`; '$postfix
unset exec_prefix
unset prefix
unset postfix

setenv MODULESHOME /usr/share/Modules

if (! $?MODULEPATH ) then
  setenv MODULEPATH `sed 's/#.*$//' ${MODULESHOME}/init/.modulespath | awk 'NF==1{printf("%s:",$1)}'`
endif

if (! $?LOADEDMODULES ) then
  setenv LOADEDMODULES ""
endif

# if MANPATH is not defined at all modules will mess up default manpath use
if (! $?MANPATH ) then
  setenv MANPATH ""
endif

# we do this in case our login shell is tcsh but pbs script is bash
if ($?PBS_ENVIRONMENT) then
  setenv BASH_ENV /etc/bashrc
endif 
